home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / EDIT2.ASM < prev    next >
Assembly Source File  |  1986-12-13  |  7KB  |  198 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * EDIT2 - Screen printer. Updates the display after each cursor
  14. *  move or file modification.
  15.  
  16.     xref    cursor,putc,printf
  17.     xdef    prtscr,exp_chr,stats,set_edit,cmd_w
  18.  
  19. #edit.h
  20.  
  21. *****************************************************************
  22. * PRTSCR - Prints screen from A5
  23. prtscr:
  24.     movem.l    d1-d5/a0,-(a7)
  25. redo:
  26.     move.l    top_lef(a5),a0    * get starting character for scrn
  27.     move.w    w_ulcy(a5),d3    * d3 is screen row number
  28. row_loop:
  29.     move.w    w_ulcx(a5),d2    * d2 is screen column number
  30.     clr.w    d5        * D5 is logical column
  31.     clr.w    d4        * D4 is actual column in line
  32.     move.w    d3,-(a7)      * Push cursor Y base location
  33.     move.w    d2,-(a7)      * Push cursor X base address
  34.     bsr    cursor        * setup cursor location
  35.     addq.l    #4,a7        * adjust stack
  36. chr_loop:
  37.     cmp.l    b_gap(a5),a0    * Test for gap
  38.     blt    sk1_ps        * Not at gap, jump by
  39.     cmp.l    e_gap(a5),a0    * Are we already past gap?
  40.     bge    sk1_ps        * Yes, jump by
  41.     move.l    e_gap(a5),a0    * move pointer past gap
  42.     move.w    d2,scr_col(a5)    * save cursor position
  43.     move.w    d3,scr_row(a5)    
  44.     move.w    d5,log_col(a5)    * Save logical column
  45.     cmp.w    w_off(a5),d4    * are we before window edge?
  46.     bge    sk2_ps        * nope.
  47.     clr.w    w_off(a5)    * set offset to zero, redraw
  48.     bra    redo
  49. sk2_ps:
  50.     cmp.w    w_lrcx(a5),d2    * are we past window edge?
  51.     ble    sk1_ps        * no, continue
  52.     sub.w    w_lrcx(a5),d4    * subtract difference
  53.     add.w    w_ulcx(a5),d4    * add screen offset
  54.     addq.w    #8,d4        * add eight for good measure
  55.     add.w    d4,w_off(a5)    * set window offset, redraw
  56.     bra    redo
  57. sk1_ps:
  58.     cmp.l    e_buf(a5),a0    * Test for end of file
  59.     bgt    sk0_ps        * jump on end of file
  60.     move.b    (a0)+,d0    * pick up printable character
  61.     cmp.b    #10,d0        * is this a newline?
  62.     beq    sk0_ps        * if yes, line is complete
  63.     bsr    exp_chr        * expand character and print
  64.     bra    chr_loop    * get next char and repeat
  65. sk0_ps:
  66.     bsr    clr_eol        * Clear to end of line
  67. row_tst:
  68.     addq.w    #1,d3        * Increment row
  69.     cmp.w    w_lrby(a5),d3    * enough lines to fill window?
  70.     blt    row_loop    * jump back if not.
  71.     move.w    scr_row(a5),-(a7) reset cursor to proper location
  72.     move.w    scr_col(a5),-(a7)
  73.     bsr    cursor        * go set cursor
  74.     addq.l    #4,a7        * adjust stack
  75.     movem.l    (a7)+,d1-d5/a0
  76.     rts
  77. *****************************************************************
  78. * EXP_CHR - expands and prints a character
  79. *  D0.B    is character to print
  80. *  D5.W is logical screen column, in/out parameter
  81. *  D4.W is column count into line, in/out parameter
  82. *  D2.W is actual screen X position, in/out parameter
  83. exp_chr:
  84.     cmp.b    #$9,d0        * Is this a tab character?
  85.     beq    tabs        * If so, expand tabs.
  86.     cmp.b    #$20,d0        * is this a control char?
  87.     blt    control        * If so, expand control char
  88.     cmp.w    w_off(a5),d4    * are we up to window edge?
  89.     blt    sk0_ex        * no, skip the printing.
  90.     cmp.w    w_lrcx(a5),d2    * are we past window edge?
  91.     bgt    sk0_ex        * if so, skip printing
  92.     move.w    d0,-(a7)    * just print regular chars
  93.     bsr    putc
  94.     addq.l    #2,a7        * adjust stack    
  95.     addq.l    #1,d2        * add 1 to screen column
  96. sk0_ex:
  97.     addq.l    #1,d5        * add 1 to logical column
  98.     addq.l    #1,d4        * add 1 to line's column count
  99.     bra    exp_exit    * processing complete
  100. tabs:
  101.     move.b    #' ',d0        * expand with spaces
  102.     bsr    exp_chr        * call recursively
  103.     move.w    d5,d1        * get copy of logical column
  104.     and.w    #7,d1        * check for tab column stop
  105.     bne    tabs        * repeat as necessary
  106.     bra    exp_exit    * leave when done
  107. control:
  108.     move.w    d0,-(a7)    * save character
  109.     move.b    #'^',d0        * pass a circumflex recursively
  110.     bsr    exp_chr        * go do it
  111.     move.w    (a7)+,d0    * retrieve character
  112.     add.b    #$40,d0        * make it printable
  113.     bsr    exp_chr        * print it out
  114.     subq.w    #2,d5        * adjust logical column
  115. exp_exit:
  116.     rts
  117. *****************************************************************
  118. * CLR_EOL - Clears to end of line
  119. *   D2.W is actual screen column
  120. clr_eol:
  121.     move.w    #'  ',-(a7)    * push spaces
  122. lp0_el:
  123.     cmp.w    w_lrcx(a5),d2    * test if we're at end of window
  124.     bgt    sk0_el        * if so, we're done
  125.     bsr    putc        * otherwise, print blank
  126.     addq.w    #1,d2        * adjust screen position
  127.     bra    lp0_el        * and repeat
  128. sk0_el:
  129.     addq.l    #2,a7        * adjust stack (remove blank)
  130.     rts
  131. *****************************************************************
  132. * STATS - prints current file stats in command window
  133. stats:
  134.     movem.l    d0/d1/a5,-(a7)
  135.     tst.w    insert(a5)      * check if insert on or off
  136.     beq    no_ins
  137.     move.l    #on,-(a7)      * push "On" message
  138.     bra    past_ins
  139. no_ins:
  140.     move.l    #off,-(a7)      * push "Off" message
  141. past_ins:
  142.     move.l    e_gap(a5),d0      * compute space available
  143.     sub.l    b_gap(a5),d0
  144.     move.w    d0,-(a7)
  145.     move.l    b_gap(a5),d0      * compute chars behind cursor
  146.     sub.l    b_buf(a5),d0
  147.     move.w    d0,-(a7)
  148.     move.w    log_col(a5),-(a7) * print logical column
  149.     move.w    log_lin(a5),-(a7) * print logical line
  150.     pea    fname(a5)      * print filename
  151.     move.l    #cmd_w,a5      * load up command window desc.
  152.     move.w    w_ulcy(a5),-(a7)  * push Y position
  153.     add.w    #1,(a7)          * adjust Y position
  154.     move.w    w_ulcx(a5),-(a7)  * push X position
  155.     move.l    #statstr,-(a7)      * push format string address
  156.     bsr    printf
  157.     add.l    #24,a7          * adjust stack
  158.     movem.l    (a7)+,d0/d1/a5
  159.     rts
  160. statstr:
  161.     dc.b    '%vFile: %-14s LN %-5u CO %-5u CH %-5u SP %-5u'
  162.     dc.b    ' Insert %-3s',0    
  163. on:    dc.b    'On',0
  164. off:    dc.b    'Off',0
  165.     dc.w    0
  166. *****************************************************************
  167. * SET_EDIT - initializes edit descriptor file parameters
  168. set_edit:
  169.     move.l    a0,-(a7)    * save caller's a0
  170.     clr.w    scr_row(a5)    * cursor Y address
  171.     clr.w    scr_col(a5)    * cursor X address
  172.     clr.w    ed_err(a5)    * edit error flag
  173.     clr.w    modify(a5)    * file modified flag
  174.     move.l    a5,a0        * descriptor base address
  175.     add.l    #buffer,a0    * offset to start of char buffer
  176.     move.l    a0,b_buf(a5)    * buffer start address
  177.     move.l    a0,b_gap(a5)    * gap starting address
  178.     move.l    a0,top_lef(a5)    * addr of top left character
  179.     move.l    a5,a0        * descriptor base address
  180.     add.l    #DESC-1,a0    * add offset to end of buffer
  181.     move.l    a0,e_buf(a5)    * buffer end address
  182.     addq.l    #1,a0        * gap end address
  183.     move.l    a0,e_gap(a5)    * gap ending address
  184.     clr.l    blk_st(a5)    * block start address
  185.     clr.l    blk_end(a5)    * block end address
  186.     clr.l    cur_lin(a5)    * address 1st char, current line
  187.     clr.w    log_lin(a5)    * cursor logical line
  188.     clr.w    log_col(a5)    * cursor logical column
  189.     clr.w    w_off(a5)    * set offset to 0
  190.     move.w    #$FFFF,insert(a5) turn insert toggle on
  191.     move.l    (a7)+,a0    * restore caller's a0
  192.     rts
  193. *****************************************************************
  194.     bss
  195. cmd_w:    ds.b    buffer        * command I/O window
  196.  
  197.     end
  198.